,通达信众赢十全十美副图指标公式（附源码破译和源码）

编程思路破译

N1赋值:3

N2赋值:5

N3赋值:9

N4赋值:13

N5赋值:21

N6赋值:34

DIFF赋值:收盘价的N3日指数移动平均-收盘价的N4日指数移动平均

DEA赋值:DIFF的N2日指数移动平均

当满足条件DIFF>DEA时,在1位置画1号图标

当满足条件DIFF<DEA时,在1位置画2号图标

A1赋值:DIFF>DEA

RSV1赋值:(收盘价-N3日内最低价的最低值)/(N3日内最高价的最高值-N3日内最低价的最低值)*100

K赋值:RSV1的N1日[1日权重]移动平均

D赋值:K的N1日[1日权重]移动平均

当满足条件K>D时,在1.1位置画1号图标

当满足条件K<D时,在1.1位置画2号图标

A2赋值:K>D

LC赋值:1日前的收盘价

RSI1赋值:(收盘价-LC和0的较大值的N2日[1日权重]移动平均)/(收盘价-LC的绝对值的N2日[1日权重]移动平均)*100

RSI2赋值:(收盘价-LC和0的较大值的N4日[1日权重]移动平均)/(收盘价-LC的绝对值的N4日[1日权重]移动平均)*100

当满足条件RSI1>RSI2时,在1.2位置画1号图标

当满足条件RSI1<RSI2时,在1.2位置画2号图标

A3赋值:RSI1>RSI2

RSV赋值:-(N4日内最高价的最高值-收盘价)/(N4日内最高价的最高值-N4日内最低价的最低值)*100

LWR1赋值:RSV的N1日[1日权重]移动平均

LWR2赋值:LWR1的N1日[1日权重]移动平均

当满足条件LWR1>LWR2时,在1.3位置画1号图标

当满足条件LWR1<LWR2时,在1.3位置画2号图标

A4赋值:LWR1>LWR2

BBI赋值:(收盘价的N1日简单移动平均+收盘价的N2日简单移动平均+收盘价的N3日简单移动平均+收盘价的N4日简单移动平均)/4

当满足条件收盘价>BBI时,在1.4位置画1号图标

当满足条件收盘价<BBI时,在1.4位置画2号图标

A5赋值:收盘价>BBI

MTM赋值:收盘价-1日前的收盘价

MMS赋值:100*MTM的N2日指数移动平均的N1日指数移动平均/MTM的绝对值的N2日指数移动平均的N1日指数移动平均

MMM赋值:100*MTM的N4日指数移动平均的N3日指数移动平均/MTM的绝对值的N4日指数移动平均的N3日指数移动平均

当满足条件MMS>MMM时,在1.5位置画1号图标

当满足条件MMS<MMM时,在1.5位置画2号图标

A6赋值:MMS>MMM

BIAS赋值:(收盘价-收盘价的N2日简单移动平均)/收盘价的N2日简单移动平均

DIF赋值:(BIAS-16日前的BIAS)

DBCD赋值:DIF的76日[1日权重]移动平均

MM赋值:DBCD的5日简单移动平均

当满足条件DBCD>MM时,在1.6位置画1号图标

当满足条件DBCD<MM时,在1.6位置画2号图标

A7赋值:DBCD>MM

持股赋值:3*(收盘价-27日内最低价的最低值)/(27日内最高价的最高值-27日内最低价的最低值)*100的5日[1日权重]移动平均-2*(收盘价-27日内最低价的最低值)/(27日内最高价的最高值-27日内最低价的最低值)*100的5日[1日权重]移动平均的3日[1日权重]移动平均,线宽为0,画红色

支撑赋值:3日内持股的最低值,线宽为0,COLOR00FFFF

下跌赋值:持股的12日简单移动平均,COLOR6B8E23,线宽为0

转向赋值:持股上穿下跌

MA1赋值:持股的5日简单移动平均

向下赋值:MA1上穿持股 AND MA1>80

当满足条件持股>下跌时,在1.7位置画1号图标

当满足条件持股<下跌时,在1.7位置画2号图标

A8赋值:持股>下跌

MT赋值:收盘价-1日前的收盘价

ZLGJ赋值:100*MT的N3日指数移动平均的N3日指数移动平均/MT的绝对值的N3日指数移动平均的N3日指数移动平均

MAZL赋值:ZLGJ的5日简单移动平均

当满足条件ZLGJ>MAZL时,在1.8位置画1号图标

当满足条件ZLGJ<MAZL时,在1.8位置画2号图标

A9赋值:ZLGJ>MAZL

PJJ赋值:以0.9为权重(最高价+最低价+收盘价*2)/4的动态移动平均

JJ赋值:1日前的PJJ的3日指数移动平均

QJJ赋值:成交量(手)/((最高价-最低价)*2-收盘价-开盘价的绝对值)

XVL赋值:如果收阳线,返回QJJ*(最高价-最低价),否则返回如果收阴线,返回QJJ*(最高价-开盘价+收盘价-最低价),否则返回成交量(手)/2+如果收阳线,返回0-QJJ*(最高价-收盘价+开盘价-最低价),否则返回如果收阴线,返回0-QJJ*(最高价-最低价),否则返回0-成交量(手)/2

HSL赋值:(XVL/20)/1.15

攻击流量赋值:((HSL*0.55+(1日前的HSL*0.33))+(2日前的HSL*0.22))

GJJ赋值:攻击流量的8日指数移动平均

LLJX赋值:攻击流量的3日指数移动平均

资金流量赋值:LLJX,线宽为0,COLOR0000FF

当满足条件资金流量>0时,在1.95位置画1号图标

当满足条件资金流量<0时,在1.95位置画2号图标

A10赋值:资金流量>0

指导线赋值:(A1+A2+A3+A4+A5+A6+A7+A8+A9+A10),线宽为0,COLORFFFF00

输出操作:如果指导线>6,返回1.1,否则返回1,线宽为3,画黄色

程序源码

N1:=3;N2:=5;N3:=9;N4:=13;N5:=21;N6:=34;

DIFF:=EMA(CLOSE,N3)-EMA(CLOSE,N4);

DEA:=EMA(DIFF,N2);

DRAWICON(DIFF>DEA,1,1);

DRAWICON(DIFF<DEA,1,2);

{DRAWTEXT(ISLASTBAR=1,1,'.MACD'),COLORFFFFFF;}

A1:=DIFF>DEA;

RSV1:=(CLOSE-LLV(LOW,N3))/(HHV(HIGH,N3)-LLV(LOW,N3))*100;

K:=SMA(RSV1,N1,1);

D:=SMA(K,N1,1);

DRAWICON(K>D,1.1,1);

DRAWICON(K<D,1.1,2);

{DRAWTEXT(ISLASTBAR=1,1.1,'.KDJ'),COLORFFFFFF;}

A2:=K>D;

LC:=REF(CLOSE,1);

RSI1:=(SMA(MAX(CLOSE-LC,0),N2,1))/(SMA(ABS(CLOSE-LC),N2,1))*100;

RSI2:=(SMA(MAX(CLOSE-LC,0),N4,1))/(SMA(ABS(CLOSE-LC),N4,1))*100;

DRAWICON(RSI1>RSI2,1.2,1);

DRAWICON(RSI1<RSI2,1.2,2);

{DRAWTEXT(ISLASTBAR=1,1.2,'.RSI'),COLORFFFFFF;}

A3:=RSI1>RSI2;

RSV:=-(HHV(HIGH,N4)-CLOSE)/(HHV(HIGH,N4)-LLV(LOW,N4))*100;

LWR1:=SMA(RSV,N1,1);

LWR2:=SMA(LWR1,N1,1);

DRAWICON(LWR1>LWR2,1.3,1);

DRAWICON(LWR1<LWR2,1.3,2);

{DRAWTEXT(ISLASTBAR=1,1.3,'.LW&R'),COLORFFFFFF;}

A4:=LWR1>LWR2;

BBI:=(MA(CLOSE,N1)+MA(CLOSE,N2)+MA(CLOSE,N3)+MA(CLOSE,N4))/4;

DRAWICON(CLOSE>BBI,1.4,1);

DRAWICON(CLOSE<BBI,1.4,2);

{DRAWTEXT(ISLASTBAR=1,1.4,'.BBI'),COLORFFFFFF;}

A5:=CLOSE>BBI;

MTM:=CLOSE-REF(CLOSE,1);

MMS:=100*EMA(EMA(MTM,N2),N1)/EMA(EMA(ABS(MTM),N2),N1);

MMM:=100*EMA(EMA(MTM,N4),N3)/EMA(EMA(ABS(MTM),N4),N3);

DRAWICON(MMS>MMM,1.5,1);

DRAWICON(MMS<MMM,1.5,2);

{DRAWTEXT(ISLASTBAR=1,1.5,'.ZLMM'),COLORFFFFFF;}

A6:=MMS>MMM;

BIAS:=(C-MA(C,N2))/MA(C,N2);

DIF:=(BIAS-REF(BIAS,16));

DBCD:=SMA(DIF,76,1);

MM:=MA(DBCD,5);

DRAWICON(DBCD>MM ,1.6,1);

DRAWICON(DBCD<MM,1.6,2);

{DRAWTEXT(ISLASTBAR=1,1.6,'.DBCD'),COLORFFFFFF;}

A7:=DBCD>MM;

持股:=3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1),LINETHICK0,COLORRED;

支撑:=LLV(持股,3),LINETHICK0,COLOR00FFFF;

下跌:=MA(持股,12),COLOR6B8E23,LINETHICK0;

转向:=CROSS(持股,下跌){ AND 下跌<30};

MA1:=MA(持股,5);

向下:=CROSS(MA1,持股) AND MA1>80;

DRAWICON(持股>下跌 ,1.7,1);

DRAWICON(持股<下跌,1.7,2);

{DRAWTEXT(ISLASTBAR=1,1.7,'.CGZ'),COLORFFFFFF;}

A8:=持股>下跌;

MT:=C-REF(C,1);

ZLGJ:=100*EMA(EMA(MT,N3),N3)/EMA(EMA(ABS(MT),N3),N3);

MAZL:=MA(ZLGJ,5);

DRAWICON(ZLGJ>MAZL,1.8,1);

DRAWICON(ZLGJ<MAZL,1.8,2);

A9:=ZLGJ>MAZL;

{DRAWTEXT(ISLASTBAR=1,1.8,'.ZLGJ'),COLORFFFFFF;}

PJJ:=DMA((HIGH+LOW+CLOSE*2)/4,0.9);

JJ:=REF(EMA(PJJ,3),1);

QJJ:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));

XVL:=IF(CLOSE>OPEN,QJJ*(HIGH-LOW),IF(CLOSE<OPEN,QJJ*(HIGH-OPEN+CLOSE-LOW),VOL/2))+IF(CLOSE>OPEN,0-QJJ*(HIGH-CLOSE+OPEN-LOW),IF(CLOSE<OPEN,0-QJJ*(HIGH-LOW),0-VOL/2));

HSL:=(XVL/20)/1.15;

攻击流量:=((HSL*0.55+(REF(HSL,1)*0.33))+(REF(HSL,2)*0.22));

GJJ:=EMA(攻击流量,8);

LLJX:=EMA(攻击流量,3);

资金流量:=LLJX,LINETHICK0,COLOR0000FF;

DRAWICON(资金流量>0,1.95,1);

DRAWICON(资金流量<0,1.95,2);

A10:=资金流量>0;

{DRAWTEXT(ISLASTBAR=1,1.89,'.ZJL'),COLORFFFFFF;}

指导线:=(A1+A2+A3+A4+A5+A6+A7+A8+A9+A10),LINETHICK0,COLORFFFF00;

操作:IF(指导线 >6 ,1.1,1),LINETHICK3,COLORYELLOW;

注：

       馆内各种公式为学习编程而保存，实战使用前一定要看其中是否有未来函数并自己亲自测试成功率，决不能依据公式名称的描述和形容去投资，据此入市造成投资损失由投资者自己承担。

       发文不易，如获益，欢迎赞赏，赞赏必复！

本站仅提供存储服务，所有内容均由用户发布，如发现有害或侵权内容，请点击举报。

股票配资啥意思